A Different Way to Build Servers

# start here!
duso -read

# look up a specific function or lib
duso -doc claude

# pick from 5 starter projects
duso -init myproject

# extract examples to local directory
duso -extract examples /tmp

# interactive REPL to test code
duso -repl

ai = require("ollama")
print(ai.prompt("sup?"))

ai = require("openai")
chat = ai.session()

while true do
  prompt = input("\n\nYou: ")

  if lower(prompt) == "exit" then break end

  write("\n\nOpenAI: ")
  busy("thinking...")
  write(chat.prompt(prompt))
end

ai = require("claude")

prompt = input("Ask the panel: ")
busy("asking...")

// build an array of functions to prompt
// each expert, then run them all in parallel
experts = ["Astronomer", "Astrologer", "Biologist", "Accountant"]
responses = parallel(map(experts, function(expert)
  return function()
    return ai.prompt(prompt, {
      system = """
        You are an expert {{expert}}. Always reason and
        interact from this mindset. Limit your field of
        knowledge to this expertise.
      """,
      max_tokens = 500
    })
  end
end))

// prepend the expert type into their response
for i = 0, 3 do
  responses[i] = """
    {{experts[i]}} says:
    {{replace(responses[i], "---", "")}}
  """
end

busy("summarizing...")
summary = ai.prompt("""
  Summarize these responses:

  {{join(responses, "\n\n---\n\n")}}

  List 3 the things they have in common.
  Then list the 3 things that are the most different.
""")

// format the markdown response for the terminal
print(markdown_ansi(summary))

# http://localhost:8080
duso -c 'http_server().start()'

// queue-main.du
queue = datastore("tasks")
queue.set("done", 0)

// Spawn 3 workers
for i = 1, 3 do
  spawn("queue-worker.du", {id = i})
end

// Queue 5 tasks
for i = 1, 5 do
  queue.push("jobs", {name = "Task {{i}}"})
end

// Wait for all to complete
queue.wait("done", 5)

// Show results
work = queue.get("results")
for job in work do
  print("✓ {{job.name}} by worker {{job.id}}")
end

// queue-worker.du
ctx = context()
id = ctx.id
queue = datastore("tasks")

while true do
  job = queue.pop_wait("jobs", timeout = 5)
  if not job then break end

  sleep(random() * 2)

  queue.push("results", {id = id, name = job.name})
  queue.increment("done")
end

// server.du
port = 3000
server = http_server({port = port})

server.route("GET", "/api/user/:id", "user-get.du")
server.route("POST", "/api/user", "user-post.du")

// make users datastore use acid-compliant persistence
users = datastore("users", {
  persist = "/tmp/users.gob",
  wal = "/tmp/users.wal",
  wal_sync_interval = 900
})

print("Server running at http://localhost:{{port}}")
server.start()

// ...script blocks while server is running...

print("Server stopped.")

// user-get.du
ctx = context()
req = ctx.request()
res = ctx.response()

user = datastore("users").get(req.params.id)

if not user then res.error(404) end

res.json({
  success = true,
  data = user
}, 200)

// user-post.du
ctx = context()
req = ctx.request()
res = ctx.response()

id = uuid()
user = parse_json(req.body)

datastore("users").set(id, user)

res.json({
  id = id,
  name = user.name
}, 201)